[Resolvido]Como esconder a Janela do Access ao executar um sistema?

Olá bom dia a todos

estou aqui para pedir mais uma ajuda.

tenho um programa em access e quando executo ele abre sempre no access a janela e eu queria q abrisse apenas a tela
login na area de Trabalho, tem como fazer fico no aguardo

tenha um bom dia

Boa noite;
Em um módulo cole a função abaixo e salve-a:

Código:

Option Compare Database
Option Explicit
'Autor de la función base: Indeterminado
'Declaraciones
Private Declare Function SetWindowLong Lib "User32" Alias "SetWindowLongA" _
(ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long

Private Declare Function GetWindowLong Lib "User32" Alias "GetWindowLongA" _
(ByVal hWnd As Long, ByVal nIndex As Long) As Long

Private Declare Function SetLayeredWindowAttributes Lib "User32" _
(ByVal hWnd As Long, ByVal crKey As Long, ByVal bAlpha As Byte, ByVal dwFlags As Long) As Long

'Constantes
Private Const GWL_EXSTYLE = (-20)
Private Const WS_EX_LAYERED = &H80000
Private Const LWA_ALPHA = &H2

Function AccessTransparente(Nivel As Integer)
'Adaptación:    Byron Contreras, febrero 08, byronlcl@gmail.com
'Objetivo:      Ajustar el nivel de transparencia de la ventana principal
'              de access. El nivel de transparencia debe estar entre 0 a 250
'.............................................................................
Dim lngHwnd As Long
    If Nivel < 0 Or Nivel > 250 Then Exit Function
    lngHwnd = Application.hWndAccessApp
    SetWindowLong lngHwnd, GWL_EXSTYLE, GetWindowLong(lngHwnd, GWL_EXSTYLE) Or WS_EX_LAYERED
    SetLayeredWindowAttributes lngHwnd, 0, Nivel, LWA_ALPHA
End Function

Para chamar a função, no evento ao abrir do form Login:

Código:

Call AccessTransparente(0)

Olá Fernado bom dia

estou feliz por vc tar me ajudando, fiz os procedimento como vc falou, funcionou legal só que ao abrir o sistema fica minimizado
e nao restaura como deve ser para ao abri nao ficar minimizado?

fico no aguardo

Boa noite Zacarias;
Me perdoe entendi outra coisa em sua mensagem, segue abaixo o código que necessita:

Em um módulo coloque:

Código:

Option Compare Database

Private Declare PtrSafe Function IsWindowVisible Lib "user32" (ByVal hwnd As Long) As Long
Dim dwReturn As Long

Const SW_HIDE = 0
Const SW_SHOWNORMAL = 1
Const SW_SHOWMINIMIZED = 2
Const SW_SHOWMAXIMIZED = 3

Private Declare PtrSafe Function ShowWindow Lib "user32" (ByVal hwnd As Long, _
ByVal nCmdShow As Long) As Long

Public Function fAccessWindow(Optional Procedure As String, Optional SwitchStatus As Boolean, Optional StatusCheck As Boolean) As Boolean
If Procedure = "Hide" Then
dwReturn = ShowWindow(Application.hWndAccessApp, SW_HIDE)
End If
If Procedure = "Show" Then
dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMAXIMIZED)
End If
If Procedure = "Minimize" Then
dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMINIMIZED)
End If
If SwitchStatus = True Then
If IsWindowVisible(hWndAccessApp) = 1 Then
dwReturn = ShowWindow(Application.hWndAccessApp, SW_HIDE)
Else
dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMAXIMIZED)
End If
End If
If StatusCheck = True Then
If IsWindowVisible(hWndAccessApp) = 0 Then
fAccessWindow = False
End If
If IsWindowVisible(hWndAccessApp) = 1 Then
fAccessWindow = True
End If
End If
End Function



No evento ao abrir do formulário:

Código:

Call fAccessWindow("minimize", False, False)

Olá bom dia a todos

venho agradecer o Fernando Bueno, por ter me ajudado fico feliz foi resolvido beleza
abraço a todos

Boa tarde Zacarias;

Que bom que resolveu sua duvida, precisando estamos por aqui.

O fórum agradece o retorno!